MPU6050 6 Eksen İvme ve Gyro Sensörü

#include<Wire.h>;                         //I2C Kütüphanesi

const int MPU_addr = 0x68;                //MPU6050 I2C Slave adresi

float old_x = 0;                          //Önceki okunan açısal hız değeri. (X ekseni için)
float old_y = 0;                          //Önceki okunan açısal hız değeri. (Y Ekseni için)
float prev_angle_x = 0;                   //Önceki okunan açı değeri. (X ekseni için)
float prev_angle_y = 0;                   //Önceki okunan açı değeri. (Y ekseni için)

unsigned long previousMillis = 0;         //Önceki millis değeri
int interval = 30;                        //Ölçümler arasındaki bekleme süresi(ms)
 
int X_offset = 520;                       //X ekseni offset değeri
int Y_offset = 0;                         //Y ekseni offset değeri
int Z_offset = 0;                         //Z ekseni offset değeri

void setup() {
  Serial.begin(9600);                                    //Seri haberlşeme başlatılır
  Serial.println ("Başlamak için bir tuşa basınız");     //Devem edilmesi için girdi beklenir (Seri)
  while (Serial.available() == 0);
  Wire.begin();                                          //I2C Başlatılır
  Wire.beginTransmission(MPU_addr);                      //0x6B register'ındaki setup değerleri 0 yapılır
  Wire.write(0x6B);
  Wire.write(0x00);
  Wire.endTransmission(true);
  Serial.begin(9600);

}

void loop() {
  unsigned long currentMillis = millis();                             //Millis değeri alınır
 
  if (currentMillis - previousMillis >= interval) {                   //İnterval süresi geçtiğinde içeri girilir
    previousMillis = currentMillis;

    Wire.beginTransmission(MPU_addr);                                 //MPU6050 ile I2C haberleşme başlatılır
    Wire.write(0x43);                                                 //Gyro bilgisinin olduğu 0x43-0x48 için request gönderilir
    Wire.endTransmission(false); 
    Wire.requestFrom(MPU_addr, 6, true);
    int16_t XGyroFull = (Wire.read() << 8 | Wire.read()) + X_offset;   //8-bitlik okunan iki değerden büyük ağırlıklı olanı 8 bit sola kaydırılıp küçük olanla veyalanır. Offset eklenir.
    int16_t YGyroFull = (Wire.read() << 8 | Wire.read()) + Y_offset;   //8-bitlik okunan iki değerden büyük ağırlıklı olanı 8 bit sola kaydırılıp küçük olanla veyalanır. Offset eklenir.
    int16_t ZGyroFull = (Wire.read() << 8 | Wire.read()) + Z_offset;   //8-bitlik okunan iki değerden büyük ağırlıklı olanı 8 bit sola kaydırılıp küçük olanla veyalanır. Offset eklenir.
    float XGyroFinal = (float)XGyroFull / 131;                         //Datasheet'te yazan değerlere göre "deg/s" cinsinden açısal hız bulunur. (X ekseni için)
    float YGyroFinal = (float)YGyroFull / 131;                         //Datasheet'te yazan değerlere göre "deg/s" cinsinden açısal hız bulunur. (Y ekseni için)
    float ZGyroFinal = (float)ZGyroFull / 131;                         //Datasheet'te yazan değerlere göre "deg/s" cinsinden açısal hız bulunur. (Z ekseni için)

    //X ekseni için açı hesabı
    float delta_angle_x = (0.03 * old_x) + ((0.03 * (XGyroFinal - old_x)) / 2); //açısal hız ve geçen süreye bağlı olarak taranan açı hesaplanır
    float angle_x = (prev_angle_x + delta_angle_x);                             //taranan açı değeri ile bir önceki açı değeri hesaplanarak 
    prev_angle_x = angle_x;                                                     //güncel açı değeri bir sonraki döngüde kullanılmak üzere önceki açı değeri olarak kaydedilir
    old_x = XGyroFinal;                                                         //güncel açısal hız değeri bir sonraki döngüde kullanılmak üzere önceki açısal hız değeri olarak kaydedilir

    //Y ekseni için açı hesabı
    float delta_angle_y = (0.03 * old_y) + ((0.03 * (YGyroFinal - old_y)) / 2); //yukarıdaki işlemlerin aynısı Y ekseni için de yapılır
    float angle_y = (prev_angle_y + delta_angle_y);
    prev_angle_y = angle_y;
    old_y = YGyroFinal;


    //Açısal hız değerleri seri porttan basılır
    Serial.print("X Axis = ");  
    Serial.print(XGyroFinal);
    Serial.print("deg/s");
    Serial.print("\t");
    Serial.print("Y Axis = ");
    Serial.print(YGyroFinal);
    Serial.print("deg/s");
    Serial.print("\t");
    Serial.print("Z Axis = ");
    Serial.print(ZGyroFinal);
    Serial.println("deg/s");

    //Açı değerleri seri porttan basılır
//    Serial.print("X angle = ");
//    Serial.print(angle_x);
//    Serial.print("");
//    Serial.print("\t");
//    Serial.print("Y angle = ");
//    Serial.println(angle_y);
  }
}